<< Click to display table of contents >> TCustomRVReportGenerator.OnError

Occurs if an error happens while generating a report.

type

  TRVReportGeneratorError = (

    // rules

    rvrgeRuleInvalidRange, rvrgeRuleOverlaps,

    // queries

    rvrgeNoQueryProcessor, rvrgeQueryExecution, 

    rvrgeRecordCountIsRequired,

    // variables

    rvrgeVariableUnknown, rvrgeVariableInvalidValue,

    rvrgeVariableInvalidName, rvrgeVariableUnsupportedObject,

    // data fields

    rvrgeFieldUnknown, rvrgeFieldInvalidValue, 

    rvrgeFieldUnsupportedType, rvrgeFieldUnknownType,

    rvrgeFieldUnknownRule,

    // fields

    rvrgeInvalidTypeCast, rvrgeInvalidFormatString,

    rvrgeCustomFieldTypeError,

    // commands

    rvrgeCommandUnknown, rvrgeCommandNeedsParam,

    rvrgeCommandDoesNotNeedParam, rvrgeCommandWrongParamValue,

    rvrgeCommandSyntaxError, rvrgeCommandUnmatched,

    rvrgeCommandMustBeInQuery, rvrgeCommandWrongContext,

    // cross-tab

    rvrgeCrossTabInvalid, rvrgeCrossTabInvalidPosition,

    rvrgeCrossTabNoRules,

    rvrgeCrossTabUnknownField,

    rvrgeCrossTabWrongContext, rvrgeCrossTabRecordDoesNotMatch,

    rvrgeCrossTabDuplicateRecords,

    rvrgeCrossTabKeyFieldInCrossTabColumn,

    rvrgeCrossTabNoCrossTabColumns, rvrgeCrossTabTooManyColumns,

    rvrgeCrossTabTooManyTotalColumns,

    // functions

    rvrgeFuncParenthesisExpected, rvrgeFuncUnknown,

    rvrgeFuncBadParam, rvrgeFuncMustBeInCrossTabSummary,

    rvrgeFuncCannotBeCalculated,

    // expressions

    rvrExpressionParserError, rvrExpressionEvaluationError,

    // others

    rvrgeInternalError

    );

 

  TRVReportGeneratorErrorEvent = procedure (

    Sender: TCustomRVReportGenerator;

    ErrorCode: TRVReportGeneratorError; 

    const RelatedText: TRVUnicodeString;

    RelatedObject: TObject; var Proceed: Boolean) of object;

 

property OnError: TRVReportGeneratorErrorEvent;

This event can be processed:

•to display an error message,

•to abort a report generation on some (or all) errors.

By default, this event is called in the context of the main process (even if reports are generated in a background thread), to allow interacting with user interface controls. If you want to call it in a thread context, exclude rvrgeOnError from SynchronizedEvents.

Parameters

ErrorCode – a code identifying the error.

RelatedText, RelatedObject provide additional information about this error.

You can assign False to Proceed to abort the report generation. In this case, this error is treated as critical, and Execute will return False.

Errors while checking table row generation rules for correctness

For this kind of errors, RelatedObject is TRVRowGenerationCustomRule.

Errors while executing a data query (such as SQL SELECT statement)

For this kind of errors, RelatedObject is either TRVRowGenerationCustomRule or TRVReportTableCellData.

Errors while processing variables

For this kind of errors, RelatedObject is TRVReportGenerationSession.

Errors while processing data fields

For this kind of errors, RelatedObject is TRVReportGenerationSession.

Common errors while processing data fields, cross-tab header fields, functions

For this kind of errors, RelatedObject is TRVReportGenerationSession.

Errors while processing commands

For this kind of errors, RelatedObject is TRVReportGenerationSession.

Errors while making a cross-tab report

Errors while processing functions

For this kind of errors, RelatedObject is TRVReportGenerationSession.

Errors while processing expressions

For this kind of errors, RelatedObject is TRVExpressionCalculator.

RelatedObject (TRVExpressionCalculator) allows receiving additional information about the reason of this error and the position in expression where it happened.

Other errors

 

Example 1

How to process error messages in OnError event.

Before using RVReportGetErrorString, call RWA_LocalizeErrorMessages.

procedure TForm1.RVReportGenerator1Error(

  Sender: TCustomRVReportGenerator;
  ErrorCode: TRVReportGeneratorError; 

  const RelatedText: TRVUnicodeString;
  RelatedObject: TObject; var Proceed: Boolean);
var
  Msg1, Msg2: TRVUnicodeString;
const
  MaxErrorCount = 1000;
begin
  if lstMessages.Items.Count = MaxErrorCount then
    lstMessages.Items.Add(RWA_GetS(rwm_log_TooManyErrors));
  if lstMessages.Items.Count > MaxErrorCount then
    exit;
  RVReportGetErrorString(ErrorCode, Msg1, Msg2, RelatedObject);
  if Msg1 <> '' then
    Msg2 := Msg1 + ': ' + Msg2;
  Msg2 := Format(String(Msg2), [RelatedText]);
  lstMessages.Items.Add(String(Msg2));
end;

 

Example 2

This example shows how to use custom error messages. This example is simplified, it does not provide detailed information about errors in expressions.

const ErrorMsg: array[TRVReportGeneratorError] of String =
 (

   'Rule error: invalid row or column range',

   'Rule error: overlapping rows',

   'Query error: can''t create query processor for %s',

   'Query error: execution error for %s',

   'Query error: this type of report requires a known record count before retrieving records',

   'Variable error: unknown variable %s',

   'Variable error: invalid value for %s',

   'Variable error: invalid name %s',

   'Variable error: unsupported object in %s',

   'Data field error: unknown field %s',

   'Data field error: invalid value for %s',

   'Data field error: unsupported field type for %s',

   'Data field error: invalid type in %s',

   'Data field error: unknown row generation rule in the field %s',

   'Field error: invalid type casting in %s',

   'Field error: invalid format string %s',

   'Field error: invalid data or format string for a custom field type',

   'Command error: unknown command %s',

   'Command error: parameters are required in %s',

   'Command error: this command must not have parameters: %s',

   'Command error: wrong parameter value: %s',

   'Command error: syntax error %s',

   'Command error: unmatched command %s',

   'Command error: a command must be in content affected by a query: %s',

   'Command error: the command is not valid in its context: %s',

   'Cross-tab error: invalid cross-tab definition',

   'Cross-tab error: invalid cross-tab header location',

   'Cross-tab error: at least one row generation rule is required',

   'Cross-tab error: unknown field %s',

   'Cross-tab error: cross-tab field must be in a cross-tab header',

   'Cross-tab error: a record does not match the cross-tab columns (will be skipped)',

   'Cross-tab error: two or more records match the same cross-tab cell (all but the first one will be skipped)',

   'Cross-tab error: the same field is used both as a key field as a cross-tab header field: %s',

   'Cross-tab error: no columns',

   'Cross-tab error: too many columns in a group',

   'Cross-tab error: too many total columns',

   'Function error: parenthesis is expected in %s',

   'Function error: unknown function %s',

   'Function error: bad parameters in %s',

   'Function error: function must be in a cross-tab summary rows or columns',

   'Function error: function cannot be calculated',

   'Expression parsing error in %s', 

   'Expression evaluation error: %s',

   'Internal error'

    );
 
procedure TForm1.RVReportGenerator1Error(

  Sender: TCustomRVReportGenerator;
  ErrorCode: TRVReportGeneratorError; 

  const RelatedText: TRVUnicodeString;
  RelatedObject: TObject; var Proceed: Boolean);
var S: TRVUnicodeString;
begin
  S := Format(ErrorMsg[ErrorCode], [RelatedText]);
  Memo1.Lines.Add(S);
end;